Библиотека DHT sensor library

Датчики температуры и влажности DHT11 и DHT22: два числа за один вызов, без разбора однопроводного протокола.

Установка и подключение

В менеджере библиотек ищите DHT sensor library автора Adafruit. Если менеджер предложит поставить зависимости — соглашайтесь. Как открыть менеджер и что делать, если библиотека не находится, — в общей статье про библиотеки.

#include <DHT.h>

Создание объекта — обычно до setup():

#define DHTPIN 2
#define DHTTYPE DHT22          // или DHT11
DHT dht(DHTPIN, DHTTYPE);
dht.begin();                   // в setup()

Методы

Только то, что нужно в обычном скетче. Сигнатуры сверены с версией 1.4.7.

begin()

Подготовить вывод. В setup().

readTemperature()

Температура в °C как float. NaN, если датчик не ответил.

readTemperature(true)

То же в °F.

readHumidity()

Влажность в процентах, float. NaN при ошибке.

computeHeatIndex(t, h, false)

«Ощущаемая» температура по температуре и влажности; false — в °C.

read(bool force)

Принудительно опросить датчик, не дожидаясь двух секунд. Возвращает true при удаче.

isnan(value)

Не метод библиотеки, а проверка из math.h: так узнают, что чтение не удалось.

Пример

#include <DHT.h>

#define DHTPIN  2
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(9600);
  dht.begin();
}

void loop() {
  delay(2000);                          // DHT22 не отвечает чаще
  float h = dht.readHumidity();
  float t = dht.readTemperature();
  if (isnan(h) || isnan(t)) {
    Serial.println("Датчик не ответил");
    return;
  }
  Serial.print(t, 1); Serial.print(" C, ");
  Serial.print(h, 0); Serial.println(" %");
}

Проверка на NaN обязательна: при плохом контакте датчик отвечает через раз, и без неё в лог полетят «nan».

На чём попадаются

Где используется на сайте

• DHT11: схема подключения и скетч
• DHT22: схема подключения и скетч